Sütundan,satıra kayıt alma

halilm · 19-06-2011, 11:27

Merhabalar,Konteynırlara paletle yükleme yapıyoruz. Hangi konteynıra hangi numaralı paletlerin konulduğunu tek satırda (ARKU8306908 1,2,3,4,5,6,7,8,9.....) görüntüleyebilirmiyim. Çalışacak sorgu tablodaki konteyner bilgilerine göre gruplama yapacak ve palet numaralarını yan yana aralarına virgül koyarak verecek. Forumda buna benzer bir örnek buldum fakat, kendi uygulamam uyarlayamadım. Yardımlarınız için şimdiden teşekkür ederim.

Taruz · 19-06-2011, 11:39

Merhaba..

Boş bir modül sayfasına bu fonksiyonu yapıştırınız..:

Kod:
Public Function ConcatRelated(strField As String, _

    strTable As String, _

    Optional strWhere As String, _

    Optional strOrderBy As String, _

    Optional strSeparator = " ") As Variant

On Error GoTo Err_Handler

    Dim rs As DAO.Recordset

    Dim rsMV As DAO.Recordset

    Dim strSql As String

    Dim strOut As String

    Dim lngLen As Long

    Dim bIsMultiValue As Boolean

    ConcatRelated = Null

    strSql = "SELECT " & strField & " FROM " & strTable

    If strWhere <> vbNullString Then

        strSql = strSql & " WHERE " & strWhere

    End If

    If strOrderBy <> vbNullString Then

        strSql = strSql & " ORDER BY " & strOrderBy

    End If

    Set rs = DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)

    bIsMultiValue = (rs(0).Type > 100)

    Do While Not rs.EOF

        If bIsMultiValue Then

            Set rsMV = rs(0).Value

            Do While Not rsMV.EOF

                If Not IsNull(rsMV(0)) Then

                    strOut = strOut & rsMV(0) & strSeparator

                End If

                rsMV.MoveNext

            Loop

            Set rsMV = Nothing

        ElseIf Not IsNull(rs(0)) Then

            strOut = strOut & rs(0) & strSeparator

        End If

        rs.MoveNext

    Loop

    rs.Close

    lngLen = Len(strOut) - Len(strSeparator)

    If lngLen > 0 Then

        ConcatRelated = Left(strOut, lngLen)

    End If

Exit_Handler:

    Set rsMV = Nothing

    Set rs = Nothing

    Exit Function

Err_Handler:

    MsgBox "Error " & Err.Number & ": " & Err.Description, vbExclamation, "ConcatRelated()"

    Resume Exit_Handler

End Function

Sonra SQL görünümünde yeni bir sorgu oluşturup bu sorguyu yazıp çalıştırınız..:

Kod:
SELECT Tablo1.KONTEYNER, 

ConcatRelated("[PALET NO]","tablo1","KONTEYNER='" & [KONTEYNER] & "'","","-") AS PALETLER

FROM Tablo1

GROUP BY Tablo1.KONTEYNER, ConcatRelated("[PALET NO]","tablo1","KONTEYNER='" & [KONTEYNER] & "'","","-")

halilm · 19-06-2011, 12:14

Foruma konumu yazdım,mutfağa kahvaltıya gittim ve döndüğümde cevap ekranımdaydı, şükranlarımı sunuyorum.Allah'ta sizin bir sıkıntınızı gidersin inşallah.

Benzer Konular...
Konu:		Yazar	Cevaplar:	Gösterim:	Son Mesaj
	Yaklaşan Tarihte Uyarı Alma	xosmaner	3	348	14-11-2025, 21:53 Son Mesaj: özgülapt
	Alt Rapordaki Sayfa Toplamını Alma	tekinuy	6	418	08-10-2025, 22:26 Son Mesaj: tekinuy
	[SORGU] Soldan 3 Değere Göre Toplam Alma	karacahil	2	347	14-05-2025, 17:03 Son Mesaj: karacahil
	[RAPOR] Raporda Hyperlink çıktı Alma	ulsogr	4	380	09-01-2025, 10:08 Son Mesaj: ulsogr
	[TABLO] Tablodan Rapor Alma	vefa1982	11	604	28-10-2024, 01:53 Son Mesaj: dsezgin
	[SORGU] Sütun Verisini Satıra çavirme	gokselbilici	2	448	13-09-2024, 12:16 Son Mesaj: gokselbilici
	Sorguda Tarihler Arası Veri Alma	metınaycıcek	8	641	18-07-2024, 14:28 Son Mesaj: metınaycıcek
	Sürekli Formda Alt Toplam Alma	ates2014	2	359	10-07-2024, 09:33 Son Mesaj: ates2014

Oturum Aç




Beni Hatırla Şifremi Unuttum?

Access SQL