SET NOCOUNT ON
 
DECLARE @BASTAR SMALLDATETIME, @SONTAR SMALLDATETIME, @FLAGS SMALLINT, @KEBIR SMALLINT
SET @BASTAR  = '01.01.2012'
SET @SONTAR  = '30.11.2012'
SET @FLAGS   = 1
SET @KEBIR   = 0
 
-- Varsa geçici tabloyu sil
IF EXISTS(SELECT * FROM tempdb.dbo.sysobjects O
 		  WHERE O.xtype = 'U' AND O.id = OBJECT_ID(N'tempdb..#TMP'))
   BEGIN  
		DROP TABLE #TMP
   END
 
-- Yeni bir geçici tablo hazırla
CREATE TABLE #TMP
    (
      [HESAP KODU] VARCHAR(20),
      [HESAP ADI] VARCHAR(255),
      [BORÇ TOPLAM] DECIMAL(18,2),
      [ALACAK TOPLAM] DECIMAL(18,2),   
      [BORÇ BAKİYE] AS CASE 
       WHEN [BORÇ TOPLAM]-[ALACAK TOPLAM] > 0 THEN [BORÇ TOPLAM]-[ALACAK TOPLAM] END,
      [ALACAK BAKİYE] AS CASE 
       WHEN [ALACAK TOPLAM]-[BORÇ TOPLAM] > 0 THEN [ALACAK TOPLAM]-[BORÇ TOPLAM] END                
     )  
 
-- Geçici tablo için index hazırla  
CREATE CLUSTERED INDEX IDX11 ON #TMP([HESAP KODU])
 
-- Alt hesapların Borç ve Alacak toplamlarını geçici tabloya aktar                  
INSERT INTO #TMP
    (             
      [HESAP KODU],
      [HESAP ADI],
      [BORÇ TOPLAM],
      [ALACAK TOPLAM]               
    )
    SELECT
        D.sKod AS [HESAP KODU],
        D.sAd AS [HESAP ADI],
        CAST(SUM(D.[BORC]) AS DECIMAL(18,2)) AS [BORÇ TOPLAM] ,
        CAST(SUM(D.[ALACAK]) AS DECIMAL(18,2)) AS [ALACAK TOPLAM]
    FROM 
        (
          SELECT 
            A.sKod,
            A.sAd,    
            CASE C.bBorcMu WHEN 'B' THEN C.ldTutar ELSE 0 END AS [BORC],
            CASE C.bBorcMu WHEN 'A' THEN C.ldTutar ELSE 0 END AS [ALACAK] 
          FROM HesapKodu A
            INNER JOIN YevmiyeHareketi C ON (A.HesapKodu_rowid = C.pHesapKodu)
            INNER JOIN YevmiyeFisi B ON ((C.lFisNo = B.lFisNo) AND (C.dtTarih = B.dtTarih))
          WHERE (B.dtTarih BETWEEN @BASTAR AND @SONTAR) AND (B.cCinsi @IN(0,1,2) )
        ) AS D
    GROUP BY D.sKod, D.sAd
 
-- Ana hesapların toplamlarını da geçici tablodan topla ve
-- yine geçici tabloya ekle
INSERT INTO #TMP
    (
      [HESAP KODU],
      [HESAP ADI],
      [BORÇ TOPLAM],
      [ALACAK TOPLAM] 
    )
    SELECT 
        E.sKod,
        E.sAd,
        SUM(F.[BORÇ TOPLAM]) AS [BORÇ TOPLAM],
        SUM(F.[ALACAK TOPLAM]) AS [ALACAK TOPLAM]
    FROM HesapKodu E INNER JOIN #TMP F ON (F.[HESAP KODU] LIKE E.sKod + '%')
    WHERE E.nChildCount > 0
    GROUP BY E.sKod, E.sAd
 
-- Son şeklini almış hale gelen geçici tabloyu listele
IF (@FLAGS = 1)
  BEGIN
    IF (@KEBIR = 1)
      SELECT
          [HESAP KODU], [HESAP ADI], 
          NULLIF([BORÇ TOPLAM], 0) AS [BORÇ TOPLAM],
          NULLIF([ALACAK TOPLAM], 0) AS [ALACAK TOPLAM],   
          [BORÇ BAKİYE], [ALACAK BAKİYE]
      FROM #TMP 
      WHERE (LEN([HESAP KODU]) = 3) ORDER BY [HESAP KODU]
    ELSE
      SELECT
          [HESAP KODU], [HESAP ADI], 
          NULLIF([BORÇ TOPLAM], 0) AS [BORÇ TOPLAM],
          NULLIF([ALACAK TOPLAM], 0) AS [ALACAK TOPLAM],   
          [BORÇ BAKİYE], [ALACAK BAKİYE]
      FROM #TMP ORDER BY [HESAP KODU]
  END
ELSE
  BEGIN
    IF (@KEBIR = 1)
      SELECT
          [HESAP KODU], [HESAP ADI], 
          NULLIF([BORÇ TOPLAM], 0) AS [BORÇ TOPLAM],
          NULLIF([ALACAK TOPLAM], 0) AS [ALACAK TOPLAM],   
          [BORÇ BAKİYE], [ALACAK BAKİYE]
      FROM #TMP
      WHERE ([BORÇ TOPLAM] != [ALACAK TOPLAM] AND LEN([HESAP KODU]) = 3) ORDER BY [HESAP KODU]
    ELSE
      SELECT
          [HESAP KODU], [HESAP ADI], 
          NULLIF([BORÇ TOPLAM], 0) AS [BORÇ TOPLAM],
          NULLIF([ALACAK TOPLAM], 0) AS [ALACAK TOPLAM],   
          [BORÇ BAKİYE], [ALACAK BAKİYE]
      FROM #TMP
      WHERE ([BORÇ TOPLAM] != [ALACAK TOPLAM]) ORDER BY [HESAP KODU]
  END
 
-- Geçici tabloyu artık sil
DROP TABLE #TMP