küçük bir sorum olacak bilgi kirliliği olmasın diye yeni konu açmadım, raporda listeleme yaparken =1 dediğimizde 1,2,3 vs diye listemize numara veriyo ,bu nu ben form a yaptığimda 1 ,1 ,1 ,1 diye gidiyo formda nasıl bir yol izlemeliyim sıra no için

2 konu arasında ilişki yok dolayısıyla yeni konu açıp örnek dosya üzerinden açıklarsanız yardımcı olmaya çalışırız.

Merhaba, zamanın birinde hocalardan biri aşağıdaki kodu eklemişti eline sağlık diyeyim, ben hep bunu kullanıyorum.
SiraNo= otomatik sıra nosuna ne isim verdiysen onu yazacaksın.
'============================================================
' Numara sırası koymak için
'============================================================
'=GetLineNumber([Form];"SiraNo";[SiraNo])

Function GetLineNumber(f As Form, KeyName As String, KeyValue)
   Dim rs As Object
   Dim CountLines As Integer

   On Error GoTo Err_GetLineNumber

   Set rs = f.Recordset.Clone

   ' Find the current record.
   Select Case rs.Fields(KeyName).Type
      ' Find using numeric data type key value?
      Case adSmallInt, adTinyInt, adBigInt, adInteger, adDecimal, adNumeric, adCurrency, adSingle, adDouble
         rs.FindFirst "[" & KeyName & "] = " & KeyValue
      ' Find using date data type key value?
      Case adDate
         rs.FindFirst "[" & KeyName & "] = #" & KeyValue & "#"
      ' Find using text data type key value?
      Case adChar, adVarChar
         rs.FindFirst "[" & KeyName & "] = '" & KeyValue & "'"
      Case Else
         MsgBox "HATA: Boş Kayıtlar Var!"
         Exit Function
   End Select

   ' Loop backward, counting the lines.
   Do Until rs.BOF
      CountLines = CountLines + 1
      rs.MovePrevious
   Loop

Bye_GetLineNumber:
         ' Return the result.
         GetLineNumber = CountLines

         Exit Function

Err_GetLineNumber:
         CountLines = 0
         Resume Bye_GetLineNumber

End Function