(31-07-2015, 23:31)lorenzo1903 demiş ki: Merhabalar,
iki tarih arasında cumartesi,pazar ve normal iş gününü hesaplatmak istiyorum.
Örnek

10.07.2015
31.07.2015 tarihleri arasındaki iş günü ve c.tesi ve pazarı

16 iş günü
3 cumartesi
3 pazar bu şekilde yazmasını nasıl sağlayabilirim.

Sub gunler59()
Dim i As Date, isgun As Long, cumartesi As Long, pazar As Long
For i = DateValue("10.07.2015") To DateValue("31.07.2015")
    If Weekday(i, 2) < 6 Then
        isgün = isgün + 1
    ElseIf Weekday(i, 2) = 6 Then
        cumartesi = cumartesi + 1
    Else
        pazar = pazar + 1
    End If
Next i
MsgBox "İşgünü : " & isgün & vbCrLf & "Cumartesi : " & _
        cumartesi & vbCrLf & "Pazar : " & pazar
End Sub

(09-08-2015, 00:13)Orion demiş ki: B1 ' e başlangıç tarihi,B2'ye Bitiş tarihi yazıldı.
Örnek dosyayı inceleyiniz.

Visual Basic

Sub gunler59()
Dim i As Date, isgun As Long, cumartesi As Long, pazar As Long
Dim baslangic As Date, bitis As Date
If Not IsDate(Range("B1").Value) Then
    MsgBox "Yanlış Başlangıç Tarih Girişi !" & vbCrLf & "İşlem Gerçekleşmedi!", vbCritical
    Range("B1").Select
    Exit Sub
End If
If Not IsDate(Range("B2").Value) Then
    MsgBox "Yanlış Bitiş Tarih Girişi !" & vbCrLf & "İşlem Gerçekleşmedi!", vbCritical
    Range("B2").Select
    Exit Sub
End If
baslangic = Range("B1").Value
bitis = Range("B2").Value
 
For i = baslangic To bitis
    If Weekday(i, 2) < 6 Then
        isgün = isgün + 1
    ElseIf Weekday(i, 2) = 6 Then
        cumartesi = cumartesi + 1
    Else
        pazar = pazar + 1
    End If
Next i
Range("E1").Value = isgün
Range("E2").Value = cumartesi
Range("E3").Value = pazar
MsgBox "Tarihler Çıkarıldı." & vbCrLf & "evrengizlen@hotmail.com", vbOKOnly, "E V R E N"
End Sub

(09-08-2015, 11:39)lorenzo1903 demiş ki: çok teşekkür ederim hocam.